Forum

Asp mail gönde...
 
Bildirimler
Hepsini Temizle

Asp mail gönderme

4 Yazılar
3 Üyeler
0 Likes
1,723 Görüntüleme
(@kemalettintaylan)
Gönderiler: 279
Reputable Member
Konu başlatıcı
 
Merhaba İletişim formunu mail bir türlü gönderimini yaptıramadım yardımcı olurmusunuz  
host.net üzerinden host ediliyor smtp 587 portunu kullanıyor 
 
Set Mail = Server.CreateObject("Persits.MailSender")
Mail.Host = "mail.alanadi.com"
Mail.From = "[email protected]"
Mail.Username = "[email protected]"
Mail.Password = "alanadi.com"
Mail.FromName = "alanadi.com - İletişim Formu"
Mail.AddBcc "[email protected]"
Mail.Subject = "İletişim Formu"
Mail.Charset="windows-1254"
Mail.IsHTML = True '(Text gönderi için False olarak set edilmeli)
Mail.Body = sHTML
On Error Resume Next
Mail.Send
Set Mail = Nothing
 
yardımlarınız için şimdiden teşekkürler 
 
Gönderildi : 28/02/2013 16:39

(@ozgurmazlum)
Gönderiler: 2209
Illustrious Member
 

Sunucunuzda Persits.MailSender çalışıyormu kontrol ettiniz mi?

 
Gönderildi : 28/02/2013 19:40

(@RagipUNAL)
Gönderiler: 171
Estimable Member
 

    Set Mail = Server.CreateObject("Persits.MailSender")
    Mail.Username = EPostaKullAdi
    Mail.Password = EPostaSifre
    Mail.Host = EPostaSunucu
    Mail.From = EPostaAdres
    Mail.Port = 587
    Mail.FromName = strFromName
    Mail.Subject = strSubject
    Mail.Body = strBody
    Mail.IsHTML = True
    Mail.AddAddress EPostaGonderen,EPostaGonderenAdi 'Formda seçilen kişi buraya.
    If Not (EPostaGonderen2 = "" or IsNull(EPostaGonderen2)) Then
    Mail.AddBcc EPostaGonderen2
    End If
    If Not (strReplyTo = "" or IsNull(strReplyTo)) Then
    Mail.AddReplyTo strReplyTo
    End If
    Mail.Charset = "UTF-8"
    On Error Resume Next
    Mail.Send
    If Err <> 0 Then
    MailGonder = GetLocalString("fnmailgonder.mailgonderilemedi","")
    Response.Write Err.Description
    Else
    MailGonder = GetLocalString("fnmailgonder.mailgonderildi","")
    End If
    Set Mail = Nothing

Ben bu şekilde kullanıyorum. Sorunsuz çalışıyor hata kodunuzda yazarsan iyi olur. Eğer gmail üzerinden göndereceksen dikkat et eski persits versionlarda çalışmaz. (Gmail için TLS true olmalı.)

 

Diğer bir örnek: Gmail için kullanabilirsiz.Oturumu sorunsuz açıp maikl gönderir.

 Set Mail = CreateObject("CDO.Message")
   
    Mail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2
    Mail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpserver") =EPostaSunucu
    Mail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 465
    Mail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = 1
    Mail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout") = 60
    Mail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = 1
    Mail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/sendusername") =EPostaKullAdi
    Mail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/sendpassword") =EPostaSifre
    Mail.Configuration.Fields.Update

    Mail.Subject=strSubject
    Mail.From=EPostaAdres
    Mail.To=EPostaGonderen
    If Not (EPostaGonderen2 = "" or IsNull(EPostaGonderen2)) Then
    Mail.Bcc = EPostaGonderen2
    End If
    If Not (strReplyTo = "" or IsNull(strReplyTo)) Then
    Mail.ReplyTo = strReplyTo
    End If 
    Mail.HtmlBody=strBody
    On Error Resume Next
    Mail.Send
    If Err <> 0 Then
    MailGonder = GetLocalString("fnmailgonder.mailgonderilemedi","")
    Response.Write Err.Description
    Else
    MailGonder = GetLocalString("fnmailgonder.mailgonderildi","")
    End If     
    Set Mail = Nothing 

 
Gönderildi : 28/02/2013 23:01

(@kemalettintaylan)
Gönderiler: 279
Reputable Member
Konu başlatıcı
 

çok teşekkürler yardımlarınız için Localhost yazdım düzeldi 🙂

 
Gönderildi : 01/03/2013 12:52

Paylaş: